nix/flake.nix

{
  description = "flake for nixos-pulse";

  nixConfig = { };

  inputs = {
    systems = {
      url = "github:nix-systems/x86_64-linux";
    };
    nixos-hardware = {
      url = "github:NixOS/nixos-hardware/master";
    };
    nixpkgs = {
      url = "github:NixOS/nixpkgs/nixos-unstable";
    };
    nixpkgs-stable = {
      url = "github:NixOS/nixpkgs/nixos-24.05";
    };
    flake-utils = {
      url = "github:numtide/flake-utils";
      inputs.systems.follows = "systems";
    };
    flake-parts = {
      url = "github:hercules-ci/flake-parts";
      inputs.nixpkgs-lib.follows = "nixpkgs";
    };
    gitignore = {
      url = "github:hercules-ci/gitignore.nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    pre-commit-hooks = {
      url = "github:cachix/pre-commit-hooks.nix";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.nixpkgs-stable.follows = "nixpkgs-stable";
      inputs.flake-compat.follows = "flake-compat";
      inputs.gitignore.follows = "gitignore";
    };
    flake-compat.url = "https://flakehub.com/f/edolstra/flake-compat/1.tar.gz";
    lanzaboote = {
      url = "github:nix-community/lanzaboote/v0.4.1";

      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
      inputs.flake-compat.follows = "flake-compat";
      inputs.pre-commit-hooks-nix.follows = "pre-commit-hooks";
      inputs.flake-parts.follows = "flake-parts";
    };
    lix-module = {
      url = "https://git.lix.systems/lix-project/nixos-module/archive/2.91.0.tar.gz";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
    };
    chaotic = {
      url = "github:chaotic-cx/nyx/nyxpkgs-unstable";
      inputs.systems.follows = "systems";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.home-manager.follows = "home-manager";
    };
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    emacs-overlay = {
      url = "github:nix-community/emacs-overlay/3052bb01d404ee9bd03b040c9ae898febca05b81";
      inputs.flake-utils.follows = "flake-utils";
      inputs.nixpkgs-stable.follows = "nixpkgs-stable";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nur = {
      url = "github:nix-community/NUR";
    };
    nix-wallpaper = {
      url = "github:lunik1/nix-wallpaper";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
      inputs.pre-commit-hooks.follows = "pre-commit-hooks";
    };
    nix-index-database = {
      url = "github:Mic92/nix-index-database";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    plasma-manager = {
      url = "github:nix-community/plasma-manager";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.home-manager.follows = "home-manager";
    };
    nix-alien = {
      url = "github:thiagokokada/nix-alien";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.nix-index-database.follows = "nix-index-database";
      inputs.flake-utils.follows = "flake-utils";
      inputs.flake-compat.follows = "flake-compat";
    };
    envfs = {
      url = "github:Mic92/envfs";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-parts.follows = "flake-parts";
    };
    nix-ld-rs = {
      url = "github:nix-community/nix-ld-rs";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-utils.follows = "flake-utils";
      inputs.flake-compat.follows = "flake-compat";
    };
    stylix = {
      url = "github:danth/stylix";
      inputs.flake-compat.follows = "flake-compat";
      inputs.flake-utils.follows = "flake-utils";
      inputs.home-manager.follows = "home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.systems.follows = "systems";
    };
    llama-cpp = {
      url = "git+https://git.vlt81.de/tristan/llama.cpp.git";
      inputs.nixpkgs.follows = "nixpkgs";
      inputs.flake-parts.follows = "flake-parts";
    };
  };

  outputs =
    { self
    , nixpkgs
    , lanzaboote
    , nixos-hardware
    , lix-module
    , home-manager
    , plasma-manager
    , emacs-overlay
    , nur
    , nix-index-database
    , disko
    , chaotic
    , envfs
    , llama-cpp
    , stylix
    , nix-wallpaper
    , ...
    } @ inputs:
    let
      system = "x86_64-linux";
      my-overlay = final: prev: {
        my = self.packages."${system}";
        nix-wallpaper = nix-wallpaper.packages."${system}".default;
      };
      overlays = [
        my-overlay
        emacs-overlay.overlay
        inputs.nix-alien.overlays.default
        inputs.nix-ld-rs.overlays.default
      ];
      config = {
        allowUnfree = true;
        permittedInsecurePackages = [
          "jitsi-meet-1.0.8043"
          # "olm-3.2.16"
        ];
      };
      pkgs = import nixpkgs {
        inherit config system overlays;
      };
      hmModules = [
        nix-index-database.hmModules.nix-index
        nur.hmModules.nur
        plasma-manager.homeManagerModules.plasma-manager
        # stylix.homeManagerModules.stylix
      ];
      osModules = [
        lanzaboote.nixosModules.lanzaboote
        lix-module.nixosModules.default
        disko.nixosModules.disko
        home-manager.nixosModules.home-manager
        nix-index-database.nixosModules.nix-index
        nur.nixosModules.nur
        chaotic.nixosModules.default
        envfs.nixosModules.envfs
        stylix.nixosModules.stylix
      ];
      args = {
        inherit self inputs system;
      };
    in
    {
      formatter = {
        ${system} = pkgs.nixpkgs-fmt;
      };
      packages."${system}" =
        let
          # list paths
          pkgs-paths-list = pkgs.lib.fileset.toList (pkgs.lib.fileset.fromSource (pkgs.lib.sources.sourceFilesBySuffices ./pkgs [ ".nix" ]));
          # filename-extension parsed out
          pkgs-paths =
            builtins.map
              (path: {
                name = pkgs.lib.strings.removeSuffix ".nix" (builtins.baseNameOf path);
                path = path;
              })
              pkgs-paths-list;
          # import each path
          imported-pkgs = pkgs.lib.attrsets.mergeAttrsList (builtins.map
            (pkg: {
              "${pkg.name}" = pkgs.callPackage pkg.path { };
            })
            pkgs-paths);
        in
        imported-pkgs;
      diskoConfigurations = {
        nixos-desk = import ./systems/nixos-desk/disko.nix;
        nixos-pulse = import ./systems/nixos-pulse/disko.nix;
        nixos-he4 = import ./systems/nixos-he4/disko.nix;
      };
      # replace this with a auto-importing variant like the packages decl. above (instead of callPackage we just need to import the path)
      nixosConfigurations = nixpkgs.lib.attrsets.mergeAttrsList (
        nixpkgs.lib.lists.forEach [
          "nixos-desk"
          "nixos-he4"
          "nixos-karl-kvm-guest"
          "nixos-pulse"
          "nixos-fw16"
          "rescue-iso"
        ]
          (host: {
            "${host}" = nixpkgs.lib.nixosSystem {
              inherit system;
              specialArgs = args;
              modules =
                [
                  ./systems/${host}
                  {
                    nixpkgs = {
                      inherit config system overlays;
                    };
                    # nixpkgs.pkgs = pkgs;
                    nix.registry.nixpkgs.flake = nixpkgs;
                    home-manager.sharedModules = hmModules;
                    home-manager.extraSpecialArgs = args;
                  }
                ]
                ++ osModules;
            };
          })
      );
    };
}